@echo off
rem ============================================================
rem  anymize fuer Word, Excel und PowerPoint  -  Installation per Doppelklick
rem
rem  Laedt das Add-in-Manifest herunter und registriert es fuer
rem  Word, Excel UND PowerPoint - nur fuer den aktuellen Benutzer,
rem  KEINE Admin-Rechte noetig.
rem
rem  Danach: Word/Excel neu starten -> Start-Ribbon -> "anymize".
rem  Nur ASCII in dieser Datei: cmd.exe zeigt Umlaute sonst falsch an.
rem ============================================================
setlocal

set "TARGETDIR=%LOCALAPPDATA%\anymize\addins"
set "MANIFEST=%TARGETDIR%\anymize-office-manifest.xml"
set "WEFKEY=HKCU\Software\Microsoft\Office\16.0\WEF\Developer"

echo.
echo  anymize fuer Word, Excel ^& PowerPoint wird installiert...
echo.

mkdir "%TARGETDIR%" 2>nul

curl.exe -fsSL "https://addins.anymize.ai/download/anymize-office-manifest.xml" -o "%MANIFEST%"
if errorlevel 1 goto :fail
echo   OK: Manifest heruntergeladen

reg add "%WEFKEY%" /v anymize-office /t REG_SZ /d "%MANIFEST%" /f >nul
if errorlevel 1 goto :fail
echo   OK: Add-in fuer Word, Excel und PowerPoint registriert

rem Alte getrennte Tester-Eintraege entfernen (sonst doppelter Button).
reg delete "%WEFKEY%" /v anymize-word  /f >nul 2>&1
reg delete "%WEFKEY%" /v anymize-excel /f >nul 2>&1

echo.
echo  Fertig! Naechste Schritte:
echo    1. Word, Excel und PowerPoint komplett schliessen und neu starten.
echo    2. Im Ribbon "Start" rechts auf den Button "anymize" klicken.
echo    3. Beim ersten Start mit dem anymize-Konto anmelden.
echo.
echo  Deinstallation: anymize-entfernen.cmd von der Download-Seite.
echo.
pause
exit /b 0

:fail
echo.
echo  FEHLER: Installation fehlgeschlagen.
echo  Bitte Internetverbindung pruefen und erneut versuchen -
echo  oder die Anleitung nutzen: https://addins.anymize.ai/download/
echo.
pause
exit /b 1